module Grep = Grep
module Common = Common
open Notty
module Input_screen = Input_screen

type state =
  { pos : int * int
  ; scroll : int
  ; content : (string * int * string * int) array
  ; go_back : unit -> unit
  ; content_pretty : Grep.display_type array
  }

let render_line size_x y scroll (el : Grep.display_type) i =
  match el with
  | Bold el ->
    if i == y - scroll
    then (
      let fill = String.make (max (size_x - String.length el) 0) ' ' in
      I.strf "%s%s" ~attr:A.(st bold ++ st reverse) el fill |> I.pad ~l:0 ~t:i)
    else I.strf "%s" ~attr:A.(st bold) el |> I.pad ~l:0 ~t:i
  | Normal el ->
    if i == y - scroll
    then (
      let fill = String.make (max (size_x - String.length el) 0) ' ' in
      I.strf "%s%s" ~attr:A.(st reverse) el fill |> I.pad ~l:0 ~t:i)
    else I.strf "%s" el |> I.pad ~l:0 ~t:i


let rec render t ({ pos; scroll; content_pretty; go_back; content } as state) =
  let size_x, size_y = Common.Term.size t in
  let x, y = pos in
  let img =
    let elements =
      Array.mapi
        (fun i el -> render_line size_x y scroll el i)
        (* TODO: Fix this ugly slow conversion *)
        (Array.to_seq content_pretty |> Seq.drop scroll |> Array.of_seq)
    in
    let open I in
    Array.fold_left (fun sum el -> el </> sum) I.empty elements
  in
  Common.Term.image t img;
  let content_length = Array.length content_pretty in
  let scroll_up () =
    let scroll = if y - scroll = 0 then max (scroll - 1) 0 else scroll in
    render t @@ { state with pos = x, max (y - 1) 0; scroll }
  in
  let scroll_down () =
    let scroll = if y - scroll >= size_y - 1 then scroll + 1 else scroll in
    render t @@ { state with pos = x, min (y + 1) (content_length - 1); scroll }
  in
  match Common.Term.event t with
  | `End | `Key (`Escape, []) | `Key (`ASCII 'q', []) | `Key (`ASCII 'C', [ `Ctrl ]) -> ()
  | `Mouse (`Press (`Scroll s), _, _) ->
    (match s with
     | `Down -> scroll_down ()
     | `Up -> scroll_up ())
  | `Resize _ -> render t state
  | `Key (`ASCII '@', []) -> go_back ()
  | `Mouse ((`Press _ | `Drag), (_, y), _) ->
    render t { state with pos = 0, min y content_length }
  | `Key (`ASCII 'j', []) | `Key (`ASCII 'N', [ `Ctrl ]) -> scroll_down ()
  | `Key (`ASCII 'k', []) | `Key (`ASCII 'P', [ `Ctrl ]) -> scroll_up ()
  | `Key (`ASCII 'e', []) | `Key (`Enter, []) ->
    (* Editor might be set with extra args, in that case we need to separate these *)
    let[@warning "-8"] (editor :: args) =
      String.split_on_char ' ' (Sys.getenv "EDITOR")
    in
    let selected_file, line_number, _, file_number_offset = Array.get content y in
    let full_path_file = Grep.execution_directory ^ "/" ^ selected_file in
    let line_number_arg = "+" ^ Int.to_string (line_number - file_number_offset) in
    let full_args =
      Array.append (Array.of_list args) [| line_number_arg; full_path_file |]
    in
    Common.Term.cursor t (Some (0, 0));
    let _ =
      Unix.create_process_env
        editor
        full_args
        (Unix.environment ())
        Unix.stdin
        Unix.stdout
        Unix.stderr
    in
    let rec run_editor () =
      match Unix.wait () with
      | _, _ ->
        Common.Term.cursor t None;
        render t state
      (* Capture resizing events *)
      | exception Unix.Unix_error (Unix.EINTR, _, _) -> run_editor ()
      | exception Unix.Unix_error (_, _, _) -> failwith "ERROR"
    in
    run_editor ()
  | `Key (`Arrow d, _) ->
    (match d with
     | `Up -> scroll_up ()
     | `Down -> scroll_down ()
     | _ -> render t state)
  | _ -> render t state