module Grep = Grep
module Common = Common
open Notty

type state =
  { user_input : string
  ; on_enter : string -> unit
  ; on_cancel : unit -> unit
  ; prompt : string
  ; screen : I.t
  }

let rec render t ({ user_input; on_enter; on_cancel; prompt; screen } as state) =
  let size_x, size_y = Common.Term.size t in
  Common.Term.cursor
    t
    (Some (String.length user_input + String.length prompt + 3, size_y));
  let img =
    let open I in
    I.strf " %s " ~attr:(A.st A.reverse) prompt
    <|> I.strf " %s%s" user_input (String.make size_x ' ')
    |> I.pad ~l:0 ~t:(size_y - 1)
    </> screen
  in
  Common.Term.image t img;
  match Common.Term.event t with
  | `End | `Key (`Escape, []) | `Key (`ASCII 'G', [ `Ctrl ]) | `Key (`ASCII 'C', [ `Ctrl ])
    -> on_cancel ()
  | `Key (`Enter, []) -> on_enter user_input
  | `Key (`Backspace, []) ->
    if String.equal "" user_input
    then on_cancel ()
    else (
      let state =
        { state with
          user_input = String.sub user_input 0 (max (String.length user_input - 1) 0)
        }
      in
      render t state)
  | `Resize _ -> render t state
  | `Key (`ASCII c, []) ->
    let state = { state with user_input = user_input ^ String.make 1 c } in
    render t state
  | _ -> render t state